# Data Dictionary configuration for MSSQL Linked Server

**URL:** <https://clarionhub.com/t/data-dictionary-configuration-for-mssql-linked-server/9232>\
**Category:** questions\
**Tags:** mssql, dictionary\
**Created:** [July 14, 2026, 9:37pm UTC](https://clarionhub.com/t/data-dictionary-configuration-for-mssql-linked-server/9232 "2026-07-14T21:37:41Z")\
**Posts on this page:** 4\
**Page:** 1

<div class="post-metadata">

**Author:** ![JoeNieters](https://clarionhub.com/letter_avatar_proxy/v4/letter/j/53a042/32.png) [@JoeNieters](https://clarionhub.com/u/JoeNieters)\
**Post date:** [July 14, 2026, 9:37pm UTC](https://clarionhub.com/t/data-dictionary-configuration-for-mssql-linked-server/9232/1 "2026-07-14T21:37:42Z")

</div>

I need to access a table on remote SQL server using a Linked Server that I have defined on our primary SQL server. I am able return results using _TABLE_{PROP:SQL} syntax, but I want to define and access the table via a table definition in the data dictionary. I’m not sure how to configure the OWNER and PATH variables. Anyone successful doing this in Clarion 11.1?

---

<div class="post-metadata">

**Author:** ![Rick\_UpperPark](https://clarionhub.com/user_avatar/clarionhub.com/rick_upperpark/32/346_2.png) [@Rick\_UpperPark](https://clarionhub.com/u/Rick_UpperPark)\
**Post date:** [July 14, 2026, 10:48pm UTC](https://clarionhub.com/t/data-dictionary-configuration-for-mssql-linked-server/9232/2 "2026-07-14T22:48:48Z")

</div>

Joel,  
You can but you have to set the VerifyViaSelect option to true. Otherwise, the driver uses the sp\_columns\_100 to obtain column information about the table and this fails on a table in another database in a linked server. This example works:

```clarion

  PROGRAM
                              MAP
                              END

GLO:DBOwner CSTRING(512)

!Freight FILE,DRIVER('MSSQL'),OWNER(GLO:DBOwner),NAME('dbo.TestLinkedServer'),PRE(FRE),CREATE,BINDABLE,THREAD ! Freight Rates       
Freight FILE,DRIVER('MSSQL'),OWNER(GLO:DBOwner),NAME('[MIRKWOOD\SQL2019].LinkedServerTest.dbo.Freight'),PRE(FRE),CREATE,BINDABLE,THREAD ! Freight Rates       
KeyByCode KEY(FRE:Code),NOCASE,PRIMARY ! Key By Code         
KeyByAcctType KEY(FRE:AccountType),DUP,NOCASE ! Key By Account Type 
KeyByAcctWeight KEY(FRE:AccountType,FRE:Weight),DUP,NOCASE ! Key By Account and Weight
Record RECORD,PRE()
Code LONG ! Freight Code        
AccountType STRING(8) ! Account Type        
MinWeight DECIMAL(9,2) ! Minimum Weight      
MinCharge DECIMAL(9,2) ! Minimum Charge      
Weight DECIMAL(9,2) ! Weight              
Rate DECIMAL(7,2) ! Rate                
                                  END
                                END                       

  
  CODE
  GLO:DBOwner = 'MIRKWOOD\SQL2022,MainDatabaseForLinkedServer'
  SEND(Freight,'/TRUSTEDCONNECTION=TRUE')
  SEND(Freight, '/VERIFYVIASELECT=TRUE' )

  IF ERRORCODE()
    MESSAGE('Failed to SEND: ' & ERROR() & ' ' & FILEERROR())
  end
  OPEN(Freight,42h)
  IF ERRORCODE()
    MESSAGE('Failed to open: ' & ERROR() & ' ' & FILEERROR())
  else
    MESSAGE('Success: ' & RECORDS(Freight))
  end
  
 

```

Another option that works without using the VERIFYVIASELECT, is to create a view in your main database that does a select on the linked server table. Then reference that view in your Clarion dictionary table NAME attribute.

---

<div class="post-metadata">

**Author:** ![Jock](https://clarionhub.com/letter_avatar_proxy/v4/letter/j/e68b1a/32.png) [@Jock](https://clarionhub.com/u/Jock)\
**Post date:** [July 15, 2026, 1:05pm UTC](https://clarionhub.com/t/data-dictionary-configuration-for-mssql-linked-server/9232/3 "2026-07-15T13:05:43Z")

</div>

Mirkwood??? Don’t know I’d trust anything outta there 🤣

---

<div class="post-metadata">

**Author:** ![Rick\_UpperPark](https://clarionhub.com/user_avatar/clarionhub.com/rick_upperpark/32/346_2.png) [@Rick\_UpperPark](https://clarionhub.com/u/Rick_UpperPark)\
**Post date:** [July 15, 2026, 1:56pm UTC](https://clarionhub.com/t/data-dictionary-configuration-for-mssql-linked-server/9232/4 "2026-07-15T13:56:20Z")

</div>

It’s important to stay on the path when working with that server.