@Echo Off
REM Place this batch file in your APP folder where the .APP and SLN etc reside
REM this will produce a Unique FileName like "Bckup_2023_09_28T20_13_33.ZIP"
CLS
setlocal
set D=%DATE:/=_%
set T=%TIME::=_%
set suffix=%D%T%T:~0,8%
Echo Date: %D%  Time: %T%  Suffix:%suffix% 
Echo ----

REM Folder to store the files/folder to be zipped etc. And the Cloud Destination folder
set BakFld="c:\temp\Backup\TheAPPFolder"
set CloudDestination="C:\Users\YourUserNAme\OneDrive\Backups Cloud\TheAPPFolder"

REM Set the File names and or extensions to INCLUDE
Set BakFiles=*.clw *.inc *.app *.dct *.cwproj *.sln *.manifest *.red *.lib *.XML *.cur *.ico *.png *.jpg *.bmp *.gif *.bat *.ini *.msbuild *.txt *.h *.html *.SBP *.TTF *.TPS

REM Set the Folders to EXCLUDE. like the folder where the exe, generated clws go etc. 
Set DirExclude=Backup OBJ log web certificates

set SrcFld="."
Set LogFile=%SrcFld%\LOG\_RoboCopy_%suffix%.LOG
set BakZip="Bckup_%suffix%.ZIP"

Echo From %SrcFld% To %BakFld% ZIP FileName %BakZip%

REM Make a LOG folder
MD LOG


:Backup
REM ROBOcopy %SrcFld% %BakFld% *.clw *.inc *.app *.dct *.cwproj *.sln *.manifest *.red *.lib *.cur *.ico *.png *.gif *.bat *.ini *.msbuild *.txt *.h /E /XD %DirExclude% /MT /R:2 /W:5  /PURGE /TEE /LOG+:%SrcFld%\_RoboCopy_%suffix%.LOG
ROBOcopy %SrcFld% %BakFld%  %BakFiles% /E /XD %DirExclude% /MT /R:2 /W:5  /PURGE /TEE /LOG+:%LogFile%

:ZIP
echo Zipping up folder %BakFld%
    echo --------------------------------
    powershell Compress-Archive -Path %BakFld%\* -DestinationPath %BakZip%
    IF ERRORLEVEL == 1 PAUSE
	
:ToCloud
Cls
Echo Transfering to the cloud folder: %CloudDestination% ...
Robocopy %SrcFld% %CloudDestination%  %BakZip% /LOG+:%LogFile% /Z

:END